import caurina.transitions.Tweener;
// カバーのサイズ
var spSize:Number = 200;
// カバーの間隔
var interval:Number = 50;
// 中心座標
var cx:Number = stage.stageWidth / 2;
var cy:Number = stage.stageHeight / 2;
// カバー配列
var coverArray:Array = [
            createCover(1, 0x0000CC),
            createCover(2, 0x0033CC),
            createCover(3, 0x0066CC),
            createCover(4, 0x0099CC),
            createCover(5, 0x00CCCC),
            createCover(1, 0x00CC00),
            createCover(2, 0x33CC00),
            createCover(3, 0x66CC00),
            createCover(4, 0x99CC00),
            createCover(5, 0xCCCC00)
            ];
// カバーの初期処理
for (var i:uint = 0, iEnd:uint = coverArray.length; i < iEnd; i++) {
  var sp:Sprite = coverArray[i];
  // 表示する
  addChild(sp);
  // ｙ座標とｚ座標の初期値を設定する
  sp.y = cy;
  sp.z = 0;
  // クリックイベントリスナを登録する
  sp.addEventListener(MouseEvent.CLICK, createClickHandler(i));
}
// カバークリックイベントハンドラを生成して戻します
function createClickHandler(idx:uint):Function {
  return function (e:MouseEvent):void {
    // クリックしたカバーのインデックスを指定して再配置
    arrangeCover(idx);
  };
}
// 初期状態で表示されるカバーのインデックス
var cIdx:uint = coverArray.length / 2;
// 配置する
arrangeCover(cIdx);
// 移動情報配列
var movingInfoArray:Array = new Array();
// 指定したインデックスを選択した状態でカバーを配置します
function arrangeCover(idx:uint) {
  // カバーにトィーンを付加する
  for (var i:uint = 0, iEnd:uint = coverArray.length; i < iEnd; i++) {
    var sp:Sprite = coverArray[i];
    if (i < idx) {
      // 指定インデックスより左ならｙ軸を中心に-90度傾ける
      addTween(sp, cx - (idx - i) * interval - spSize /2, spSize / 2, -90);
    } else if (i > idx) {
      // 指定インデックスより右ならｙ軸を中心に90度傾ける
      addTween(sp, cx + (i - idx) * interval + spSize / 2, spSize / 2, 90);
    } else {
      addTween(sp, cx, 0, 0);
    }
  }
  // 重ね順を更新する
  for (i = 0; i < idx; i++) {
    addChild(coverArray[i]);
  }
  for (i = coverArray.length - 1; i > idx; i--) {
    addChild(coverArray[i]);
  }
  addChild(coverArray[idx]);
}
// 指定したオブジェクトにトィーンを付加します
function addTween(sp:Sprite, newX:Number, newZ:Number, newRotationY:Number):void {
  Tweener.addTween(sp, {
           x:newX,
           z:newZ,
           rotationY:newRotationY,
           time:0.3,
           delay:0,
           transition:"easeOutSine"
             });
}
// 背景色
var bgColor:uint = 0x000000;
// サンプル用のカバームービークリップを生成して戻します
function createCover(num:uint, col:uint):Sprite {
  var sp:Sprite = new Sprite();
  // 背景を描画する
  sp.graphics.beginFill(col);
  sp.graphics.drawRect(0, 0, spSize, spSize);
  sp.graphics.endFill();
  // ラインを描画する
  sp.graphics.beginFill(0xFFFFFF);
  for (var i:uint = 0; i < num; i++) {
    var w:Number = spSize / num;
    var lw:Number = 10;
    var lx:Number = i * w + w / 2 - lw / 2;
    sp.graphics.drawRect(lx, 10, lw,spSize - 20);
  }
  sp.graphics.endFill();
  // グラデーションを描画する
  var mtx:Matrix = new Matrix();
  mtx.createGradientBox(spSize, spSize, 0, 0, 0);
  sp.graphics.beginGradientFill(GradientType.LINEAR,
                                          [0xFFFFFF, 0xFFFFFF],
                                          [0.8, 0.0],
                                          [0x00, 0xFF],
                                          mtx);
  sp.graphics.drawRect(2, 2, spSize - 4, spSize - 4);
  sp.graphics.endFill();
  // 床面反射を生成する
  var bd:BitmapData = new BitmapData(sp.width, sp.height, true, 0x000000);
  mtx = new Matrix();
  mtx.scale(1.0, -1.0);
  mtx.ty = sp.height;
  var rect:Rectangle = new Rectangle(0, 0, sp.width, sp.height);
  bd.draw(sp, mtx, new ColorTransform(), BlendMode.NORMAL, rect, true);
  var reflect:Bitmap = new Bitmap(bd);
  reflect.smoothing = true;
  // 床面反射のグラデーションを生成する
  var reflectGrad:Shape = new Shape();
  var g:Graphics = reflectGrad.graphics;
  mtx = new Matrix();
  mtx.createGradientBox(reflect.width, reflect.height, Math.PI / 2);
  g.beginGradientFill(GradientType.LINEAR, [bgColor, bgColor], [0.4, 1.0], [0, 255], mtx);
  g.moveTo(0, 0);
  g.lineTo(0, reflect.height);
  g.lineTo(reflect.width, reflect.height);
  g.lineTo(reflect.width, 0);
  g.lineTo(0, 0);
  g.endFill();
  // カバーを生成
  var cover:Sprite = new Sprite();
  sp.x = -spSize / 2;
  sp.y = -spSize / 2;
  cover.addChild(sp);
  reflect.x = -spSize / 2;
  reflect.y = spSize / 2;
  cover.addChild(reflect);
  reflectGrad.x = reflect.x;
  reflectGrad.y = reflect.y;
  cover.addChild(reflectGrad);
  return cover;
}